
**Moving annual total**

A common way to aggregate data over several months is by using the moving annual total instead of the year-to-date. The moving annual total includes the last 12 months of data. For example, the moving annual total for March 2008 includes data from April 2007 to March 2008.



The Sales MAT measure defines a range over the Year Month Number column that includes the months of one complete year from the last month in the filter context:

Sales MAT :=

VAR MonthsInRange = 12

VAR LastMonthRange = MAX ( 'Date'[Year Month Number] )

VAR FirstMonthRange = LastMonthRange - MonthsInRange + 1

VAR Result =

    CALCULATE (

        [Sales Amount],

        REMOVEFILTERS ( 'Date' ),

        'Date'[Year Month Number] >= FirstMonthRange

            && 'Date'[Year Month Number] <= LastMonthRange

    )

RETURN

    Result

The moving annual total uses [**DATESINPERIOD**](https://dax.guide/datesinperiod/?aff=dax-patterns) to select the previous year:

Sales MAT :=

IF (

    [ShowValueForDates],

    CALCULATE (

        [Sales Amount],

        DATESINPERIOD (

            'Date'[Date],

            MAX ( 'Date'[Date] ),

            -1,

            YEAR

        )


    )

)

[**DATESINPERIOD**](https://dax.guide/datesinperiod/?aff=dax-patterns) returns the set of dates starting from the date passed in the second argument and applying an offset specified in the third and fourth arguments. For example, the Sales MAT measure returns the dates included in the full year before the last date available in the filter context. The same result could have been obtained by specifying -12 and [**MONTH**](https://dax.guide/month/?aff=dax-patterns) in the third and fourth arguments, respectively.

## Moving annual total growth

The moving annual total growth is computed with the Sales PYMAT, Sales MATG, and Sales MATG % measures, which rely on the Sales MAT measure. The Sales MAT measure provides a correct value one year after the first sale ever (when it collects one full year of data), and it is not protected in case the current time period is shorter than a full year. For example, the amount for the full year 2009 of Sales PYMAT is 9,927,582.99, which corresponds to the Sales Amount of 2008 as shown in Figure 17. When compared with sales in 2009, this produces a comparison of less than 8 months – data being only available until August 15, 2009 – with a full year 2008. Similarly, you can see that Sales MATG % starts in 2008 with very high values and stabilizes after a year. The first values are due to the effect of having no sales in the previous year. This behavior is by design: the moving annual total is usually computed at the month or day granularity to show trends in a chart.



Sales PYMAT :=

VAR MonthsInRange = 12

VAR LastMonthRange =

    MAX ( 'Date'[Year Month Number] ) - MonthsInRange

VAR FirstMonthRange =

    LastMonthRange - MonthsInRange + 1

VAR Result =

    CALCULATE (

        [Sales Amount],

        REMOVEFILTERS ( 'Date' ),

        'Date'[Year Month Number] >= FirstMonthRange

            && 'Date'[Year Month Number] <= LastMonthRange

    )

RETURN

    Result

or

Sales PYMAT :=

IF (

    [ShowValueForDates],

    CALCULATE (

        [Sales MAT],

        DATEADD ( 'Date'[Date], -1, YEAR )

    )

)

Sales MATG :=

VAR ValueCurrentPeriod = [Sales MAT]

VAR ValuePreviousPeriod = [Sales PYMAT]

VAR Result =

    IF (

        NOT ISBLANK ( ValueCurrentPeriod )

            && NOT ISBLANK ( ValuePreviousPeriod ),

        ValueCurrentPeriod - ValuePreviousPeriod

    )

RETURN

    Result

Sales MATG % :=

DIVIDE (

    [Sales MATG],

    [Sales PYMAT]

)

The Sales PYMAT measure can also be written using [**SAMEPERIODLASTYEAR**](https://dax.guide/sameperiodlastyear/?aff=dax-patterns) as in the following example, which internally uses [**DATEADD**](https://dax.guide/dateadd/?aff=dax-patterns) as in the previous example:

Sales PYMAT (2) :=

IF (

    [ShowValueForDates],

    CALCULATE (

        [Sales MAT],

        SAMEPERIODLASTYEAR ( 'Date'[Date] )

    )

)